Scenes in Actionscript 3 - actionscript-3

Question

Is there a way to set up scenes in AS3, without using the Flash tool? Basically when someone clicks a button I want to present a completely different screen. Right now if I try to draw a bitmap the bitmap starts at the upper left corner of the button rather than at the upper left corner of the program display.
This is easy using Flash, you just use gotoAndPlay(1, scenename). However, I want this program to be entirely in AS3 without using Flash.
Suggestions?

Answer 1

You'll have to create your own collection of classes that represent scenes. This also involves some type of foundation to run your scenes ontop of, managing loading and unloading those scenes and their content.
In a simple scenario, this would begin as something along the lines of:
class SceneManager extends Sprite
{
private var _currentScene:Scene;
public function loadScene(scene:Scene):void
{
unloadCurrentScene();
_currentScene = scene;
_currentScene.load(this);
addChild(_currentScene.view);
}
public function unloadCurrentScene():void
{
if(hasScene)
{
_currentScene.unload(this);
_currentScene.view.parent === this && removeChild(_currentScene.view);
}
_currentScene = null;
}
public function get currentScene():Scene{ return _currentScene; }
public function get hasScene():Boolean{ return _currentScene !== null; }
}
With the Scene class:
class Scene
{
private var _view:Sprite;
public function Scene()
{
_view = new Sprite();
}
public function load(sceneManager:SceneManager):void
{
// Abstract.
// Load children, initialize components, etc.
}
public function unload(sceneManager:SceneManager):void
{
// Abstract.
// Remove children, event listeners, references, etc.
}
public function get view():Sprite{ return _view; }
}
Used like (assuming you have a class MainMenuScene extending Scene):
var sceneManager:SceneManager = new SceneManager();
addChild(sceneManager);
sceneManager.loadScene( new MainMenuScene() );