ASPJson and Mandrill API - json

Question

I am using the aspJSON Class:
http://www.aspjson.com/
To try and write some simple JSON to use for a basic test on the Mandrill email API:
https://mandrillapp.com/api/docs/messages.JSON.html#method=send
I wrote a simple bit of JSON using the "write.asp" example from the aspJSON page via this basic test:
<!--#include file="aspJSON.asp" -->
<%
Set oJSON = New aspJSON
'Write single value
oJSON.data("familyName") = "Smith"
'Make collection
Set oJSON.data("familyMembers") = oJSON.Collection()
'Add instances to collection
Set newitem = oJSON.AddToCollection(oJSON.data("familyMembers"))
newitem.add "firstName", "John"
newitem.add "age", 41
newitem.add "gender", "Male"
Set newitem = oJSON.AddToCollection(oJSON.data("familyMembers"))
newitem.add "firstName", "Suzan"
newitem.add "age", 38
newitem.add "gender", "Female"
Set newitem = oJSON.AddToCollection(oJSON.data("familyMembers"))
newitem.add "firstName", "John Jr."
newitem.add "age", 11
newitem.add "gender", "Male"
'Return the object
Response.Write oJSON.JSONoutput()
%>
That works for quite a "flat" JSON structure which like this:
{
"familyName": "Smith",
"familyMembers":
[
{
"firstName": "John",
"age": 41,
"gender": "Male"
},
{
"firstName": "Suzan",
"age": 38,
"gender": "Female"
},
{
"firstName": "John Jr.",
"age": 11,
"gender": "Male"
}
]
}
But what I'm struggling with is how to write a JSON string like the one shown in the Madrill docs, where the nesting is deeper than shown on the aspJSON example.
For example, this is an extract for the Mandrill JSON string:
{
"key": "example key",
"message": {
"html": "<p>Example HTML content</p>",
"text": "Example text content",
"subject": "example subject",
"from_email": "message.from_email#example.com",
"from_name": "Example Name",
"to": [
{
"email": "recipient.email#example.com",
"name": "Recipient Name",
"type": "to"
}
],
"headers": {
"Reply-To": "message.reply#example.com"
},
"async": false,
"ip_pool": "Main Pool",
"send_at": "example send_at"
}
As you can see for the "to" and "headers" section, the level of nesting is deeper than on the aspJSON example.
I tried this in my ASP code:
<!--#include file="aspJSON.asp" -->
<%
Set oJSON = New aspJSON
'Write single value
oJSON.data("key") = "MY_KEY"
'Make collection
Set oJSON.data("message") = oJSON.Collection()
'Add instances to collection
Set newitem = oJSON.AddToCollection(oJSON.data("message"))
newitem.add "text", "Hello world!"
newitem.add "subject", "Test Subject"
newitem.add "from_email", "me#you.com"
newitem.add "from_name", "Bob Holnas"
Set newitem = oJSON.AddToCollection(oJSON.data("to"))
newitem.add "email", "him#her.com"
newitem.add "name", "Arthur Smith"
newitem.add "type", "to"
Set newitem = oJSON.AddToCollection(oJSON.data("headers"))
newitem.add "Reply-To", "us#them.com"
'Return the object
Response.Write oJSON.JSONoutput()
%>
But got this error:
AddToCollection Error error '800a0001'
Not a collection.
/websites/aspJSON/aspJSON.asp, line 77
I have locally hosted the data from "aspJSON.asp" on my site here:
http://jimpix.co.uk/aspJSON.txt
As it is not available via the aspJSON site.
Any advice would be very much appreciated, as I am really stuck!
Thanks

Answer 1

First let me say I've never used this class before.
After studying the class, I wrote an example and tried to be helpful in the comments.
Hope it helps.
<!--#include file="aspJSON.asp" -->
<%
Set oJSON = New aspJSON
With oJSON.data
.Add "key", "MY_KEY"
.Add "message", oJSON.Collection()
With oJSON.data("message")
.Add "text", "Hello world!"
.Add "subject", "Test Subject"
.Add "from_email", "me#you.com"
.Add "from_name", "Bob Holnas"
.Add "to", oJSON.Collection()
With .Item("to")
'To obtain a collection will be considered an array for output, specify integer keys instead of string
.Add 0, oJSON.Collection() 'first index is a collection
With .Item(0) 'add key-value pairs to first index of the collection
.Add "email", "him#her.com"
.Add "name", "Arthur Smith"
.Add "type", "to"
End With
End With
.Add "headers", oJSON.Collection()
With .Item("headers")
.Add "Reply-To", "us#them.com"
End With
End With
'.Add "async", false
'.Add "ip_pool", "Main Pool"
'.Add "send_at", "example send_at"
End With
Response.Write oJSON.JSONoutput()
%>
Given output:
{
"key": "MY_KEY",
"message": {
"text": "Hello world!",
"subject": "Test Subject",
"from_email": "me#you.com",
"from_name": "Bob Holnas",
"to": [
{
"email": "him#her.com",
"name": "Arthur Smith",
"type": "to"
}
],
"headers": {
"Reply-To": "us#them.com"
}
}
}