Stage resizing in AS3 Flash - actionscript-3

Question

Heyyyy, i'm trying to find a simple way ( or as simple as possible, i'm a newbie in AS3) to resize stage while doing a mouse over event. For details, the original size is 670x40 and the target size is 670x230. Also, please answer for movieclip.

Answer 1

You can't dynamically change the stage size from code, but You can change it with the JS.
See here.

Answer 2

Sorry, this is an old post, but I hope this could help someone, I saw a lot of problems and confusions between stage.width, stage.height and stage.stageWidth, stage.stageHeight...
All you've to know is that you must use stage.align = StageAlign.TOP_LEFT or StageAlign.TOP and stage.scaleMode = StageScaleMode.NO_SCALE;
All should be works fine then...
This is a way to re size some content when an Event.Resize is triggered...
Create a Main.as class file in a "com" package (copy paste the simple code here bellow to figure you out how it may works) and set the main class in flash to "com.Main".
Why do you want to do it when a MouseEvent is triggered?
Seems like nonsense...
The Event.RESIZE is more efficient AMHO in this case.
The Event.ADDED will initialize the items you want to resize...
package com
{
import flash.display.Graphics;
import flash.display.MovieClip;
import flash.display.Stage;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.events.Event;
import flash.text.TextField;
public class Main extends MovieClip
{
public static const ORANGE:int = 0xff9900;
private var bg:MovieClip;
private var bg_mask:MovieClip;
private var marginx:int = 10;
private var marginy:int = 10;
private var display:MovieClip;
private var displayTextField:TextField;
private var ellipseWidth:int = 90;
private var ellipseHeight:int = 90;
public function Main()
{
super();
bg = new MovieClip();
bg_mask = new MovieClip();
display = new MovieClip();
displayTextField = new TextField();
this.addChild(bg);
this.addChild(bg_mask);
this.addChild(display);
this.display.addChild(displayTextField);
displayTextField.text = "";
displayTextField.x = ellipseWidth/Math.PI;
displayTextField.y = ellipseHeight/Math.PI;
stage.align = StageAlign.TOP_LEFT; // or StageAlign.TOP
stage.scaleMode = StageScaleMode.NO_SCALE;
drawBackground();
display.mask = bg_mask;
addListeners();
}
private function drawBackground(thickness:int=1,lineColor:int=0x000000,lineAlpha:Number=0.5,fillColor:int=ORANGE,fillAlpha:Number=0.5):void{
var g:Graphics = bg.graphics;
g.clear();
g.lineStyle(thickness,lineColor,lineAlpha);
g.beginFill(fillColor,fillAlpha);
g.drawRoundRect(marginx,marginy,this.stage.stageWidth-marginx*2,this.stage.stageHeight-marginy*2,ellipseWidth,ellipseHeight);
g.endFill();
}
private function drawMask():void{
var g:Graphics = bg_mask.graphics;
g.clear();
g.lineStyle(1,0x000000,0.3);
g.beginFill(0xcccccc,0.1);
g.drawRoundRect(marginx,marginy,this.stage.stageWidth-marginx*2,this.stage.stageHeight-marginy*2,90,90);
g.endFill();
}
private function addListeners():void{
stage.addEventListener(Event.ADDED,updateLabel);
stage.addEventListener(Event.RESIZE,updateLabel);
}
private function updateLabel(e:Event):void{
updateDisplay();
drawBackground();
drawMask();
}
private function updateDisplay():void{
var tf:TextField = displayTextField;
tf.text = ("{" + this.stage.stageWidth + ";" + this.stage.stageHeight + "}");
}
}
}