as3 textarea focus event bug - actionscript-3

Question

I'm not sure how long this has existed, it seems to have just come up for the first time.
If you create a TextArea component (author or runtime) and give it focus, you'll get 3 focus events.
create a new as3 fla, drag the TextArea component into your library and paste this on frame 1.
import flash.events.FocusEvent;
import fl.controls.TextArea;
var field = new TextArea();
addChild(field);
var field2 = new TextArea();
field2.x = 150;
addChild(field2);
field.addEventListener(FocusEvent.FOCUS_IN, onFocusIn);
function onFocusIn(event:FocusEvent):void{
trace(event.target);
}
Now click on the left field. Do you see 3 trace statements?
Any idea how to fix this?

Answer 1

You receive multiple FocusEvents, because TextArea contains a TextInput that it controls. When you Focus on the TextArea, the focus is actually given to the TextInput and you receive a focus event for the TextArea, and another for the TextInput.
The best way to limit the number of received event is to check if the target of the event is the same that the target you actually listen.
function onFocusIn(event:FocusEvent):void{
if (event.target == event.currentTarget) {
trace(event.target); // only the focus events generated by the TextArea.
}
}
EDIT So, I got back to the code with the issue about clicks, and the actual fix is really tricky. In fact, the source of the error was a combination of various same issues.
First : the fact that TextArea and the inner TextField both send Event at the beginning.
Second : After the beginning, when the TextField receive focus from a click, it is blocked by the parent.
And Third : When the focus come from out of the swf, in your case, the focus event is send two times (dunno why).
In order to fix it correctly, I had to listen to the unknown TextField within the TextArea (instead of the TextArea itself), and keep track of the focus leaving the Stage in order to inhibit the first of the two events generated. Which gives this :
import flash.events.FocusEvent;
import fl.controls.TextArea;
var stageFocus:Boolean = true;
var field = new TextArea();
addChild(field);
var field2 = new TextArea();
field2.x = 150;
addChild(field2);
field.addEventListener(FocusEvent.FOCUS_IN, onFocusIn);
function onFocusIn(event:FocusEvent):void{
if (event.target == event.currentTarget) {
if (event.target is TextField) {
if (stageFocus) {
// Finally ! one event at a Time and no miss.
trace(DisplayObject(event.target).parent);
} else {
stageFocus = true;
}
}
} else {
event.target.addEventListener(FocusEvent.FOCUS_IN, onFocusIn);
field.removeEventListener(FocusEvent.FOCUS_IN, onFocusIn);
}
}
// check if the focus leave the stage (the user clic out of the swf)
stage.addEventListener(FocusEvent.FOCUS_OUT, onStageFocusOut);
function onStageFocusOut(event:FocusEvent) {
if (event.relatedObject == null) {
stageFocus = false;
}
}