Action Script 3. Delete object when mouse clicked - actionscript-3

Question

I'm creating flash game, Idea is falling objects (in this case apples) from the sky and player need to click on apples, after apple is clicked It must be deleted and Score updated by 10 points.
Here is my part of code where apples is spawning:
public function startGame()
{
speed = C.PLAYER_SPEED;
gravity = C.GRAVITY;
score = C.PLAYER_START_SCORE;
randomChance = C.APPLE_SPAWN_CHANCE;
apples = new Array();
mcGameStage.addEventListener(Event.ENTER_FRAME,update);
}
private function update(evt:Event)
{
//Spawn new apples
if (Math.random() < randomChance)
{
var newApple = new Apple();
newApple.x = Math.random() * C.APPLE_SPAWN_END_X + C.APPLE_SPAWN_START_X;
newApple.y = C.APPLE_START_Y;
apples.push(newApple);
mcGameStage.addChildAt(newApple,0);
}
//Move Apples
for (var i = apples.length-1; i >= 0; i--)
{
apples[i].y += gravity;
if (apples[i].y > C.APPLE_END_Y)
{
mcGameStage.removeChild(apples[i]);
apples.splice(i,1);
}
}
//txtScore.text = String(score);
}
}
And here is code which should delete apples by mouse clicked. But It doesn't work, I don't have any errors, just not deleting apples. Could you help me please?
function onClick(evt:MouseEvent):void{
var apples = evt.target;
for (var iz = apples.length-1; iz >= 0; iz--)
{
//Register hit
score += C.SCORE_PER_APPLE;
mcGameStage.removeChild(apples[iz]);
apples.splice(iz,1);
}
}
UPDATE
So my code now looks like:
public function startGame()
{
speed = C.PLAYER_SPEED;
gravity = C.GRAVITY;
score = C.PLAYER_START_SCORE;
randomChance = C.APPLE_SPAWN_CHANCE;
apples = new Array();
mcGameStage.addEventListener(Event.ENTER_FRAME,update);
}
private function update(evt:Event)
{
//Spawn new apples
if (Math.random() < randomChance)
{
var newApple = new Apple();
newApple.x = Math.random() * C.APPLE_SPAWN_END_X + C.APPLE_SPAWN_START_X;
newApple.y = C.APPLE_START_Y;
apples.push(newApple);
newApple.addEventListener(MouseEvent.CLICK, onClick);
mcGameStage.addChildAt(newApple,0);
}
//Move Apples
for (var i = apples.length-1; i >= 0; i--)
{
apples[i].y += gravity;
if (apples[i].y > C.APPLE_END_Y)
{
mcGameStage.removeChild(apples[i]);
apples.splice(i,1);
}
}
txtScore.text = String(score);
}
function onClick(evt:MouseEvent):void{
var apples = evt.target;
apples.visible = false;
//mcGameStage.removeChild(apples);
score += C.SCORE_PER_APPLE;
}
}
}
I use this apples.visible = false; instead mcGameStage.removeChild(apples); and It's all right.
Just I misunderstood why my score not updating? Always show 0.
And sometimes I can't set apples invisible by 1 click If it is click on top of apple nothing happens, I need to click on apple's center to hide It, why I have this problem?

Answer 1

If you are serious about game development, you should think about code bloat. In your case, you don't need any apples array - your display list, courtesy Flash Player, is already able to contain the apples in a sorted linked list structure - much more efficient for the kind use you intend for it - deleting and adding apples. If you dedicate a container sprite just for containing apples, you get two benefits: 1) you get a free display list of apples and 2) if you register a mouse click event listener for this sprite (which contains only apples), then every click is on an apple and event.target will reflect it.
Review the altered code carefully:
public function startGame()
{
speed = C.PLAYER_SPEED;
gravity = C.GRAVITY;
score = C.PLAYER_START_SCORE;
randomChance = C.APPLE_SPAWN_CHANCE;
mcApples = new Sprite();
mcApples.addEventListener(MouseEvent.CLICK, onClickApple);
mcGameStage.addChild(mcApples);
mcGameStage.addEventListener(Event.ENTER_FRAME, update);
}
private function update(evt:Event)
{
//Spawn new apple
if(Math.random() < randomChance)
{
var newApple = new Apple();
newApple.x = Math.random() * C.APPLE_SPAWN_END_X + C.APPLE_SPAWN_START_X;
newApple.y = C.APPLE_START_Y;
mcApples.addChild(newApple);
}
//Move Apples
for (var i = 0; i < mcApples.numChildren;)
{
var apple = mcApples.getChildAt(i);
apple.y += gravity;
if(apple.y > C.APPLE_END_Y)
{
apple.parent.removeChild(apple);
continue;
}
i++;
}
}
function onClickApple(event: MouseEvent):void
{
var apple : Apple = event.target;
apple.parent.removeChild(apple);
score += C.SCORE_PER_APPLE;
}
The important changes and their effects are thus:
Dedicated sprite mcApples where apples are added and removed from.
No need for an array of apples, Flash Player keeps track of apples in mcApples container.
Mouse clicking listener setup guarantees any click is on an apple.
So, no splicing of arrays required and no need for explicit function references in Apple class or adding event listener for each new apple.
As an extra piece of advice, you should be careful binding your logic to enter frame events - the faster the frame rate, the faster the call frequency - usually no problem, but sometimes not what you want. I would bind the update call to a timer event instead ;-)

Answer 2

private function update(evt:Event)
{
//Spawn new apples
if (Math.random() < randomChance)
{
var newApple = new Apple(appleClick);
newApple.x = Math.random() * C.APPLE_SPAWN_END_X + C.APPLE_SPAWN_START_X;
newApple.y = C.APPLE_START_Y;
apples.push(newApple);
mcGameStage.addChildAt(newApple,0);
}
//Move Apples
for (var i = apples.length-1; i >= 0; i--)
{
apples[i].y += gravity;
if (apples[i].y > C.APPLE_END_Y)
{
mcGameStage.removeChild(apples[i]);
apples[iz].destruct();
apples.splice(i,1);
}
}
//txtScore.text = String(score);
}
function appleClick(pApple:Apple):void{
for (var iz = apples.length-1; iz >= 0; iz--)
{
if (apples[iz] == pApple)
{
//Register hit
score += C.SCORE_PER_APPLE;
mcGameStage.removeChild(apples[iz]);
apples[iz].destruct();
apples.splice(iz,1);
break;
}
}
}
....
public class Apple extends Group or something
{
private var m_fCallback:Function;
public function Apple(pCallback:Function):void
{
addEventListener(MouseEvent.CLICK, onClick);
m_fCallback = pCallback;
}
private function destruct():void
{
removeEventListener(MouseEvent.CLICK, onClick);
}
private function onClick(pEvent:MouseEvent):void
{
m_fCallback(this);
}
}

Answer 3

I do not see any event listener added for onClick(). Be sure to check that your event listener is added, and put a trace or an alert in your onClick() function so that you can confirm that the code is actually reached.