Dynamic Y Position of TextField through iterations of a loop - actionscript-3

Question

I have a function called dataLoaded that has multiple loops through a nested array full of ingredient items. The aim is to insert each item from the array into a TextField which forms part of a scrolling list. My array structure is like so:
public var so:SharedObject = SharedObject.getLocal("mySharedObject");
public var meat_items_array:Array = new Array(so.data.meat1, so.data.meat2, so.data.meat3);
public var carb_items_array:Array = new Array(so.data.carbs1, so.data.carbs2, so.data.carbs3);
public var other_items_array:Array = new Array(so.data.other1, so.data.other2, so.data.other3);
public var mealtype_items_array:Array = new Array(so.data.mealtype1, so.data.mealtype2, so.data.mealtype3);
public var cuisine_items_array:Array = new Array(so.data.cuisine1, so.data.cuisine2, so.data.cuisine3);
public var veg_items_array:Array = new Array(so.data.veg1, so.data.veg2, so.data.veg3);
public var master_array:Array = new Array(meat_items_array, carb_items_array, other_items_array, mealtype_items_array, cuisine_items_array, veg_items_array);
Here is my dataLoaded function:
private function dataLoaded():void
{
for ( var masterCounter:int = 0; masterCounter < master_array.length; masterCounter++ )
{
for (var nestedCounter:int=0;nestedCounter<master_array[masterCounter].length;nestedCounter++)
{
var txt:String = master_array[masterCounter][nestedCounter];
if (txt==null) continue;
populateItem(txt,nestedCounter);
}
}
}
Originally all of the aesthetic positioning of items in the scrolling list below were done within the dataLoaded function but I have now decided to move all of these things into a new function called populateItems which is called during every iteration of the inner for loop in dataLoaded.
This all works well, except for the fact that the line _item.y = nestedCount * _itemPosition; no longer works as it should (originally items would be placed sequentially in a list, with the y value being calculated by multiplying a constant (_itemPosition) by the value of the counter for each iteration of the inner for loop). Now, 3 items are inputted into the list at once, and in the next iteration of the loop, another 3 items are placed right on top of the previous 3 items, obscuring them.
How do I change my below function so that my _itemPosition is more dynamic through the iterations of the dataLoaded function?
function populateItem(txt:String, nestedCount:Number):void {
_item = new Item();
_item.item_btn_over.alpha = 0;
_itemTextField = new TextField();
_itemTextField.x = _textFieldXPosition;
_itemTextField.y = _textFieldYPosition
_itemTextField.text = txt;
//adds textfield to displaylist//
_item.addChild(_itemTextField);
//vertical positioning//
_item.y = nestedCount * _itemPosition; // ????
//adds items to container displaylist//
_container.addChild(_item);
}

Answer 1

I'm not entirely clear as to what your trying to do, but assuming this code only runs once, this should do what you want:
_item.y = _container.height + padding; //this will always put the next item at the bottom of the container after the previous one (padding can be any number you want)
Here is how this works, let's say you have 3 objects that you are sequentially adding to container in a loop and you're giving each item the y value of container.height. Let's also assume each item has a height of 10:
Loop 1:
Container height is 0 (since there are presently no items in it)
So item1's y is 0
after container.addChild(item1) container
height becomes 10 (the height of item1)
Loop 2:
item2's y is set to container.height, which is presently 10
after container.addChild(item2) container height becomes 20
Loop 3:
item3's y is set to container.height, which is presently 20
after container.addChild(item3) container height becomes 30
If your code is being run multiple times (so _container already has objects in it), then simply run a function like this whenever you need to rearrange:
function orderItem():void {
var padding:int = 5; //5 pixel gap between items
var tmpY:Number = 0;
var tmpItem:DisplayObject;
for(var i:int=0;i<_container.numChildren;i++){
tmpItem = _container.getChildAt(i);
tmpItem.y = tmpY;
tmpY += tmpItem.height + padding;
}
}
This goes through every child of _container and stacks the items vertically.
As an aside, it would be much cleaner to take all this:
_item.item_btn_over.alpha = 0;
_itemTextField = new TextField();
_itemTextField.x = _textFieldXPosition;
_itemTextField.y = _textFieldYPosition
_itemTextField.text = txt;
//adds textfield to displaylist//
_item.addChild(_itemTextField);
and put it in the constructor of Item, then pass in txt as a constructor argument