Geolocation StatusEvent Never Fires - actionscript-3

Question

I am developing an AIR for iOS app and I have just this one issue left on my list of bugs to fix. Basically, when a certain window is opened, the user is able to use their current position to search. I am using the Geolocation class for this and it works fine, except for the fact that StatusEvent.STATUS is not firing. The user is prompted to give permission to use their current location, as it should, but when they choose, my StatusEvent handler is never called.
if ( Geolocation.isSupported ) {
var geo:Geolocation = new Geolocation();
geo.addEventListener( StatusEvent.STATUS, this.geolocationStatusHandler );
this.geolocationStatusHandler();
}
protected function geolocationStatusHandler( e:StatusEvent = null ):void{
var geo:Geolocation = new Geolocation();
this.gpsButton.enabled = !geo.muted;
}
The only thing I can think of is that the alert window (which freezes app execution) is opened with new Geolocation(), before I add the event listener. But if that were the case, calling the handler manually wouldn't occur until after the user closed the Alert (it happens at the same time, roughly. A breakpoint there stops the app while the alert is open)
Is there a solution for this? I could always move the prompt to the very beginning of the app, but I personally prefer not being prompted until it is needed.
Details:
ActionScript Mobile project built with AIR 3.6 SDK
Tested on iPad 2, 3, and Mini, all running iOS 6.1.3
Tested in both release and debug modes

Answer 1

Listen for the GeolocationEvent.UPDATE event.
Also, it appears you're manually calling the handler immediately after the listener; then your handler is instantiating a new Geolocation instead of getting GeolocationEvent latitude and longitude.
Example implementation using Google Geocoding API from XpenseIt tutorial:
package
{
import flash.events.Event;
import flash.events.EventDispatcher;
import flash.events.GeolocationEvent;
import flash.sensors.Geolocation;
import mx.rpc.AsyncResponder;
import mx.rpc.AsyncToken;
import mx.rpc.events.FaultEvent;
import mx.rpc.events.ResultEvent;
import mx.rpc.http.HTTPService;
[Event(name="locationUpdate", type="flash.events.Event")]
public class GeolocationUtil extends EventDispatcher
{
protected var geo:Geolocation;
public var updateCount:int;
protected var service:HTTPService = new HTTPService();
public var location:String;
public var longitude:Number;
public var latitude:Number;
public function GeolocationUtil()
{
service.url = "https://maps.googleapis.com/maps/api/geocode/xml";
}
public function geoCodeAddress(address: String):AsyncToken
{
return service.send({address: address, sensor: Geolocation.isSupported});
}
public function getLocation():void
{
if (Geolocation.isSupported)
{
geo = new Geolocation();
geo.setRequestedUpdateInterval(500);
updateCount = 0;
geo.addEventListener(GeolocationEvent.UPDATE, locationUpdateHandler);
}
}
protected function locationUpdateHandler(event:GeolocationEvent):void
{
// Throw away the first location event because it's almost always the last known location, not current location
updateCount++;
if (updateCount == 1) return;
if (event.horizontalAccuracy <= 150)
{
trace("lat:" + event.latitude + " long:" + event.longitude + " horizontalAccuracy:" + event.horizontalAccuracy);
geo.removeEventListener(GeolocationEvent.UPDATE, locationUpdateHandler);
geo = null;
}
longitude = event.longitude;
latitude = event.latitude;
var token:AsyncToken = service.send({latlng: latitude+","+longitude, sensor: Geolocation.isSupported});
token.addResponder(new AsyncResponder(
function(event:ResultEvent, token:AsyncToken):void
{
// Map the location to city and state from the response address component
location = event.result.GeocodeResponse.result[0].address_component[3].long_name + ', '+ event.result.GeocodeResponse.result[0].address_component[5].long_name;
dispatchEvent(new Event("locationUpdate"));
},
function (event:FaultEvent, token:AsyncToken):void
{
// fail silently
trace("Reverse geocoding error: " + event.fault.faultString);
}));
}
}
}