Countdown timer for time-based game - actionscript-3

Question

I have a game in which the objective is to shoot as many (randomly generated) enemy ships as possible but I want to add a 30 second timer counting down to zero to add a time limit in, but I am not sure how I would do it? I have several AS files with all of my code in to generate different sized ships at different speeds and whatnot, so if snippets of code are needed, I will add them.
I tried doing it this way and it didn't work:
var gameTime:Number = 30;
var gameTimer:Timer;
static var timeText:TextField = new TextField();
timeText = new TextField();
timeText.x = 560;
timeText.y = 0;
timeText.text = gameTime.toString();
addChild(timeText);
gameTimer = new Timer(30000, gameTime);
gameTimer.addEventListener(TimerEvent.TIMER, gameTimeCount);
gameTimer.start();
function gameTimeCount(e:TimerEvent):void
{
gameTime--;
timeText.text = gameTime.toString();
}
But the count stays at 30 and doesn't go down.
What I have now:

Answer 1

Here's one way you could do this :
// in class variable declarations
public var gameTime:int;
public var levelDuration:int;
// where you want to start it
levelDuration = 30;
gameTime = levelDuration;
var gameTimer:Timer = new Timer(1000,levelDuration);
gameTimer.addEventListener(TimerEvent.TIMER, updateTime);
gameTimer.addEventListener(TimerEvent.TIMER_COMPLETE, timeExpired)
gameTimer.start();
function updateTime(e:TimerEvent):void
{
// your class variable tracking each second,
gameTime--;
//update your user interface as needed
}
function timeExpired(e:TimerEvent):void
{
var gameTimer:Timer = e.target as Timer;
gameTimer.removeEventListener(TimerEvent.TIMER, updateTime)
gameTimer.removeEventListener(TimerEvent.TIMER, timeExpired)
// do whatever you need to do for game over
}
This code works just fine, you need to do as the updateTime function comment suggests :
//update your user interface as needed
Based on your code in your post, you need to adjust that function to look like this :
function updateTime(e:TimerEvent):void
{
trace(gameTime);
// your class variable tracking each second,
gameTime--;
//update your user interface as needed
timeHeader.text = "Time : " + String(gameTime);
}
I added a trace too, so you can see that it is indeed updating each second.