Using a form to display previous entries and add new ones - ms-access

Question

I'm trying to design a simple wildlife tracking DB, so that when myself or my colleagues spot an animal we can enter its ear tag number via a form. That will either bring us up a list of previous dates/locations that animal was observed, or if it's not in the DB, allow us to enter the new animal and location.
I have two main data tables:
dt_Animal - which stores the ear tag info, species, and other information about that unique animal
dt_Sightings - stores info on when/where animals been seen (linked to dt_Animal in a one-to-many relationship, of course)
What I want is that when you open up the form, you get a box (text or combo) to enter the animal's ear tag ID.
If the ID already exists in the DB, it brings up all the info on that animal and its previous sightings - with the option to fill out any missing info and (of course) to add a new sighting - and it WILL NOT add a new record to dt_Animal - just to dt_Sightings
If the ID doesn't exist in the DB, it creates a new record in dt_Animal and allows you to enter any/all of the other information
Where I'm running into problems is that I don't want duplicate records in dt_Animal - each animal is unique.
So far, I've gotten it so that if the eartagID value you've entered is already present in dt_Animal, instead of just popping up a warning, the form will bring up the associated data in the 'Sightings' subform, so you can see where the animal has been previously as well as add your new sighting.
Any help would be appreciated! I had been getting some help at another forum until the person helping me was banned for a fracas on another thread...!
http://www.access-programmers.co.uk/forums/showthread.php?p=1249087
Thanks!

Answer 1

If you haven't tried it already, I would suggest using a Form for Animals that uses standard text boxes, combo boxes, etc., to display/edit the animals' details and uses a linked Subform control to display/edit their sightings all at once, like this:
The main form is bound to [dt_Animal], so you don't run the risk of creating duplicates in that table if [eartagID] is the Primary Key (which it should be). The "Sightings" subform is bound to [dt_Sightings] and linked to [dt_Animal] by [eartagID], so
it only shows the Sightings for the current Animal
if you add a new Sighting it will automatically link that Sighting to the current Animal (i.e., automatically insert the correct [dt_Sightings].[eartagID]).
Edit
To make searching/adding animals more "seamless", one approach would be to add a text box txtAddSearch and a command button cmdAddSearch to the form header with the following code behind the form:
Option Compare Database
Option Explicit
Private Sub cmdAddSearch_Click()
Dim rst As DAO.Recordset
If Not IsNull(Me.txtAddSearch.Value) Then
Set rst = Me.RecordsetClone
rst.FindFirst "eartagID=" & Me.txtAddSearch.Value
If rst.NoMatch Then
DoCmd.GoToRecord acDataForm, Me.Name, acNewRec
Me.eartagID.SetFocus
Me.eartagID.Text = Me.txtAddSearch.Value
Me.species.SetFocus
Else
Me.Bookmark = rst.Bookmark
End If
Set rst = Nothing
End If
End Sub
Private Sub Form_Load()
Me.cmdAddSearch.Default = True
Me.txtAddSearch.SetFocus
End Sub
When the form first loads you are looking at the first data record, but txtAddSearch has the focus:
You type in an EarTagID and hit [Enter]. If the record already exists then you are taken to it...
...and if the EarTagID doesn't already exist you are taken to a new record (with that EarTagID already filled in) so you can add the details: