Flash restart functions after completion - actionscript-3

Question

I have made this code which works fine - my problem is that at the end i wish to make it start over.
When i started making this my intent was, that the .swf movie would just loop when it ended - but that does not happen.
Then i figured that i would try and make a sort of "restart" function in the code itself that would reset the timer and strings..
I have googled around and tried a couple of things myself - But to no luck at all..
First i tried to reset the variable i. Then i tried to remove the timer eventListeners. But with no succes.
What would be the best way to go about getting this code to start over again?
import flash.utils.Timer;
import flash.events.TimerEvent;
import com.greensock.*;
import com.greensock.easing.*;
var str_one:String = 'På fredag udkommer metroXpress, som du kender den, for sidste gang... ';
var i:uint = 0;
var timer_one:Timer = new Timer(50);
timer_one.start();
timer_one.addEventListener(TimerEvent.TIMER, goTime);
var str_two:String = 'På fredag udkommer metroXpress, som du kender den, for sidste gang... Fra 2. april bliver du mødt af en helt ny avis, med det bedste fra den gamle, tilsat en masse nyt.';
var timer_two:Timer = new Timer(50);
timer_two.addEventListener(TimerEvent.TIMER, goTime_two);
var str_three:String = 'På fredag udkommer metroXpress, som du kender den, for sidste gang... Fra 2. april bliver du mødt af en helt ny avis, med det bedste fra den gamle, tilsat en masse nyt.Sådan vil vi skabe en endnu bedre avis til dig, der er på farten. Glæd dig – det gør vi!';
var timer_three:Timer = new Timer(50);
timer_three.addEventListener(TimerEvent.TIMER, goTime_three);
function goTime(e:TimerEvent) {
tekstbox1_txt.appendText(str_one.charAt(i));
i++;
if (i>=str_one.length) {
timer_one.stop();
TweenLite.to(hand, 1, {y:175, onComplete:ripwhite});
}
}
function ripwhite():void {
TweenLite.to(hand, 1, {y:405});
TweenLite.to(white_mask, 1, {y:320, onComplete:fadetekst1ud});
}
function fadetekst1ud():void {
TweenLite.to(tekstbox1_txt, 1, {alpha:0, onComplete:tekstnr2});
}
function tekstnr2():void {
timer_two.start();
}
function goTime_two(e:TimerEvent) {
tekstbox2_txt.appendText(str_two.charAt(i));
i++;
if (i>=str_two.length) {
timer_two.stop();
TweenLite.to(tekstbox2_txt, 1, {alpha:1, onComplete:forsinkelse});
}
}
function forsinkelse():void {
TweenLite.to(tekstbox2_txt, 1, {alpha:0, onComplete:tekstnr3});
}
function tekstnr3():void {
timer_three.start();
}
function goTime_three(e:TimerEvent) {
tekstbox3_txt.appendText(str_three.charAt(i));
i++;
if (i>=str_three.length) {
timer_three.stop();
TweenLite.to(tekstbox3_txt, 1, {alpha:1, onComplete:sidstefunktion});
}
}
function sidstefunktion():void {
TweenLite.to(tekstbox3_txt, 1, {alpha:0});
TweenLite.to(rippedpic, 1, {alpha:0});
}
EDIT:
When setting up a reset function and then making it loop back to my initial function like this:
function nulstil():void {
i = 0;
TweenLite.killTweensOf(hand);
TweenLite.killTweensOf(tekstbox1_txt);
TweenLite.killTweensOf(tekstbox2_txt);
TweenLite.killTweensOf(tekstbox3_txt);
timer_one.addEventListener(TimerEvent.TIMER, goTime);
timer_two.addEventListener(TimerEvent.TIMER, goTime_two);
timer_two.addEventListener(TimerEvent.TIMER, goTime_three);
TweenLite.to(white_mask, 0.1, {onComplete:goTimeAgain});
}
I get the following in the output:
ArgumentError: Error #1063: Argument count mismatch on Untitled_fla::MainTimeline/goTimeAgain(). Expected 1, got 0.
at Function/http://adobe.com/AS3/2006/builtin::apply()
at com.greensock.core::TweenCore/complete()
at com.greensock::TweenLite/renderTime()
at com.greensock.core::SimpleTimeline/renderTime()
at com.greensock::TweenLite$/updateAll()

Answer 1

I suggested in a comment that you use TimelineMax. Here's the full code that I think should work. Note carefully where I use the offset argument of append and where I don't. You'll need to fill out the resetEverything function to set all the visual elements to their proper starting positions, alphas, etc.
Basically how this works: Instead of using Timers we use the addCallback feature of TimelineMax. Callbacks have "length" of 0 in the timeline, so you have to manually advance the playhead when you are attaching the callbacks, and when you add the first tween after each batch of callbacks (that's where we use the offset argument). Tweens do have a length, though, so subsequent calls to append will automatically align the tweens to the end of the timeline as built up to the that point.
In the constructor of the TimelineMax we specified repeat : -1, which will cause the timeline to loop forever. Finally, we added the resetEverything callback at the very beginning so that every time the timeline restarts we are assured that all the elements are in the correct start position. The rest is completely automatic, handled by the timeline.
import com.greensock.*;
var str_one:String = 'På fredag udkommer metroXpress, som du kender den, for sidste gang... ';
var str_two:String = 'Fra 2. april bliver du mødt af en helt ny avis, med det bedste fra den gamle, tilsat en masse nyt.';
var str_three:String = 'Sådan vil vi skabe en endnu bedre avis til dig, der er på farten. Glæd dig – det gør vi!';
//-------- HELPER FUNCTIONS ---------//
// Set everything to start positions
function resetEverything():void {
// Set alphas, positions, etc.
hand.x = <start x>;
hand.y = <start y>;
//
}
// Quick reusable callback
function addText(textBox:TextField, text:String):void { textBox.appendText(text); }
//-------- BUILD THE TIMELINE ---------//
var timeline:TimelineMax = new TimelineMax({repeat : -1}); //repeat = -1 --> loop forever
timeline.pause();
timeline.addCallback(resetEverything, 0);
var lng:uint = str_one.length;
var playHead:Number = 0.05;
for(var i:uint = 0; i < lng; i++) {
timeline.addCallback(addText, playHead, [tekstbox1_txt, str_one.charAt(i)]);
playHead += 0.05;
}
timeline.append(new TweenLite(hand, 1, {y:175}), lng * 0.05); // !!Note the offset argument here!!
timeline.append(new TweenLite(hand, 1, {y:405}));
timeline.append(new TweenLite(white_mask, 1, {y:320}));
timeline.append(new TweenLite(tekstbox1_txt, 1, {alpha:0}));
playHead += 4;
lng = str_two.length;
for(i = 0; i < lng; i++) {
timeline.addCallback(addText, playHead, [tekstbox2_txt, str_two.charAt(i)]);
playHead += 0.05;
}
timeline.append(new TweenLite(tekstbox2_txt, 1, {alpha:1}), lng * 0.05); // !!Note the offset argument here!!
timeline.append(new TweenLite(tekstbox2_txt, 1, {alpha:0}));
playHead += 2;
lng = str_three.length;
for(i = 0; i < lng; i++) {
timeline.addCallback(addText, playHead, [tekstbox3_txt, str_three.charAt(i)]);
playHead += 0.05;
}
timeline.append(new TweenLite(tekstbox3_txt, 1, {alpha:1}), lng * 0.05); // !!Note the offset argument here!!
timeline.append(new TweenLite(tekstbox3_txt, 1, {alpha:0});
timeline.append(new TweenLite(rippedpic, 1, {alpha:0});
timeline.play();