Adding Event Listeners to Buttons - actionscript-3

Question

I am new to Actionscript and I am creating a simple addition game where the player will click on numbers 1 through 9 on the bottom of the screen to solve an addition problem. Should I create individual buttons or movieclips on the bottom?
How do I add event listeners to the buttons/movieclips to be able to tell if the player clicked the second button as opposed to other buttons on the screen. Thank you!

Answer 1

Pretty similar to Ronnie's solution (I was almost finished this so had to post) and it is tested:
import flash.display.MovieClip;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.events.MouseEvent;
import flash.text.TextFormat;
var buttonCount = 9;
var buttonSize = 50;
var button:MovieClip;
var label:TextField;
for (var i:int = 0; i < buttonCount; i ++)
{
// Create a new MovieClip
button = new MovieClip();
// We'll use this in the event handler to identify which button was clicked
button.id = i + 1;
// Draw the background in the graphics prop of the MovieClip
button.graphics.beginFill(0x00ff00, 1);
button.graphics.drawRect(0, 0, buttonSize, buttonSize);
// Add event listener
button.addEventListener(MouseEvent.CLICK, this.clickHandler);
// Position the button
button.x = i * (buttonSize + 20); // Add some spacing
button.y = stage.stageHeight - buttonSize - 10;
// Add the button to the stage
addChild(button);
// Create the label for the button
label = new TextField();
label.text = button.id.toString();
label.selectable = false;
label.multiline = false;
label.autoSize = TextFieldAutoSize.LEFT;
label.setTextFormat(new TextFormat('Arial', 12, 0, true));
// Position the label in the centre of the button
label.x = (buttonSize - label.width) / 2;
label.y = (buttonSize - label.height) / 2;
// Add the label to the button MovieClip
button.addChild(label);
}
function clickHandler(event:MouseEvent):void
{
trace("Button clicked:", event.currentTarget.id);
}

Answer 2

What I would do is make a single movie clip with a text field in it. For example, I have a movie clip (with a linkage name of NumClip) and a dynamic text field inside called numText (Be sure to embed numerals or whatever other characters you need). Then a simple for loop should do the trick.
var maxNum:Number = 9;
for (var i:int = 1; i <= maxNum; i++)
{
var clip:NumClip = new NumClip();
clip.x = i * (clip.width + 5);
clip.y = 50;
clip.id = i;
clip.numText.text = String(i);
clip.addEventListener(MouseEvent.CLICK, numClick);
addChild(clip);
}
function numClick(e:MouseEvent):void
{
trace("You clicked number " + e.currentTarget.id);
}
I haven't tested this code, but it looks good to me and should do the trick