Starling onClick method - actionscript-3

Question

I'm using starling framework, to simulate onclick method I use this code:
if(e.getTouch(this).phase == TouchPhase.ENDED){
//Some code
}
It's OK, but it also fires, if the mouse is not over the button anymore, however I'd like it to dispatch only if it's over. Is there any way to achieve this?
thanks
in the code, "this" is a Sprite, It's kinda irrelevant thougth

Answer 1

According to the docs the interactsWith(target:DisplayObject) method of the TouchEvent class should return true if the target is currently being touched. I have no way to test this theory, but the following should work:
if (e.getTouch(this).phase == TouchPhase.ENDED && e.interactsWith(this)) {
//The touch ended on the same DisplayObject as it originated at
}

Answer 2

How about this idea:
if ( e.getTouch( this ).phase == TouchPhase.ENDED ) {
if ( this.hitTestPoint( stage.mouseX, stage.mouseY, true ) ) {
// Some code
}
}

Answer 3

The easy way would be to use a starling.display.Button to do it. they dispatch TRIGGERED Events, which are basically what you want. The 'not so easy' way is to keep track of your touches, by replicating what is actually done in Button :
private function onTouch(event:TouchEvent):void
{
var touch:Touch = event.getTouch(this);
if (!mEnabled || touch == null) return;
if (touch.phase == TouchPhase.BEGAN && !mIsDown)
{
//equivalent to MOUSE_DOWN
mIsDown = true;
}
else if (touch.phase == TouchPhase.MOVED && mIsDown)
{
// reset button when user dragged too far away after pushing
var buttonRect:Rectangle = getBounds(stage);
if (touch.globalX < buttonRect.x - MAX_DRAG_DIST ||
touch.globalY < buttonRect.y - MAX_DRAG_DIST ||
touch.globalX > buttonRect.x + buttonRect.width + MAX_DRAG_DIST ||
touch.globalY > buttonRect.y + buttonRect.height + MAX_DRAG_DIST)
{
mIsDown = false;
}
}
else if (touch.phase == TouchPhase.ENDED && mIsDown)
{
mIsDown = false;
//this is a click
dispatchEventWith(Event.TRIGGERED, true);
}
}
you'l have to change the buttonRect code to reflect your sprite's shape, but basically here you are.