Detect changes in a tk::text widget - widget

Question

I want to monitor every change in a tk::text widget.
My first step was simply to get all <Key> events and send them to my monitoring routine, but if I copy some text into the text widget, this will not work.
I found a <Modified> virtual event. This will give me the ability to react on every change in the text widget, but I did not find a way to determine the kind of change.
For my actual problem it would be sufficient if I got every character or text which were inserted into my widget. It is not important to get the positions or other attributes of the insertion.
The next thing I tried was to bind the <Button-2> event. This will give me a notification but I could not get the inserted text. Is there maybe a way to get the actual selected text from X which would be copied into the widget? This would also be sufficient.

Answer 1

If you just want notification of inserts, deletes and replaces (which all other modifications boil down to) the simplest way is to intercept the insert, delete and replace methods. Here's how to do it with a TclOO wrapper:
oo::class create Text {
unexport destroy
constructor {w} {
rename $w [namespace current]::realwidget
bind $w <Destroy> [namespace code {my destroy}]
}
self method create {w args} {
rename [my new [::text $w {*}$args]] ::$w
return $w
}
method DoingModification args {
# Override this method to find out
}
method delete args {
my DoingModification {*}$args
tailcall realwidget delete {*}$args
}
method insert args {
my DoingModification {*}$args
tailcall realwidget insert {*}$args
}
method replace args {
my DoingModification {*}$args
tailcall realwidget replace {*}$args
}
}
# Everything else should just be forwarded; there's a lot of methods to do
# so we loop over them all...
foreach method {
bbox cget compare configure count debug dlineinfo dump edit get image
index mark peer scan search see tag window xview yview
} {
oo::define Text forward $method realwidget $method
}
After that, you can make a widget and find out the modifications pretty easily, and everything otherwise works just like normal:
set w [Text create .t]
oo::objdefine $w method DoingModification {method args} {
puts "Doing a $method on $args"
}
pack $w