Failing to catch an exception in SML due to syntax error - exception

Question

I'm trying to add the mechanism of catching an exception after throwing it
previously in code , but I can't get it to compile :
Here's the code without exception handling - it compiles and works great :
fun calc(input : string ) : int =
let
val outStr = ref "someString"
val outInt = ref 0
in
(
outStr := replaceRomanDec(input); (* replace roman number with decimal *)
outInt := calcMyRomanExpression(!outStr)
);
(!outInt)
end;
But when I try to put handle and exception , here :
fun calc(input : string ) : int =
exception CalculatorParser
let
val outStr = ref "someString"
val outInt = ref 0
in
(
outStr := replaceRomanDec(input); (* replace roman number with decimal *)
outInt := calcMyRomanExpression(!outStr);
handle CalculatorParser => -1
);
(!outInt)
end;
I get :
stdIn:1761.2-1761.28 Error: syntax error: deleting EXCEPTION ID
- );
=
= (!outInt)
=
=
=
= end;
stdIn:1576.1-1757.2 Error: syntax error: deleting RPAREN SEMICOLON
-
I tried to add/remove a semicolon as was suggested in the error ,but nothing worked .
Any idea what's wrong ?
Kind regards

Answer 1

It seems that you have missunderstod how sequence (expr_1; expr_2; ...; expr_n) of expressions work.
First off, there is no need to first "group" the outStr and outInt in their own sequence, just to use that in another sequence.
Secondly, we don't need parenthesis around a sequence insice the in ... end part of a local declaration (let), as there is a derived form (syntactic sugar) to handle that.
Also, there is no need to add parenthesis around a "dereference".
So a simplified version looks like this.
fun calc (input : string ) : int =
let
val outStr = ref "someString"
val outInt = ref 0
in
outStr := replaceRomanDec input; (* replace roman number with decimal *)
outInt := calcMyRomanExpression (!outStr);
!outInt
end
The grammar for handle is:
exp ::= ... | exp handle match | ...
Thus, the left hand side of handle, must be an expression. You have placed it as the last part of a sequence (exp_1 ; expr_2; expr_3):
expr_1 => outStr := replaceRomanDec(input);
expr_2 => outInt := calcMyRomanExpression(!outStr);
expr_3 => handle CalculatorParser => -1
From the we see that there is not supplied an expression to the left of handle. Thus you get an syntax error.
Since the result of your exception handling is -1, I assume it is the calcMyRomanExpression that throws the CalculatorParser exception. A solution could thus be:
fun calc(input : string ) : int =
let
val outStr = ref "someString"
val outInt = ref 0
in
outStr := replaceRomanDec(input); (* replace roman number with decimal *)
outInt := (calcMyRomanExpression(!outStr) handle CalculatorParser => ~1);
!outInt
end
Also remember that minus one is ~1 in SML.
As I noted in a comment to your question, you really ought to stop using references when doing functional programming. If you need to use them, then you are almost always doing it wrong.
If you had kept it functional, then the code could have been as simple as:
fun calc1 input = (calcMyRomanExpression o replaceRomanDec) input
or even simpler
val calc2 = calcMyRomanExpression o replaceRomanDec