gnuplot output filename from csv file - csv

Question

I have a CSV file and I am plotting the columns one by one in a do for[] loop. I would like to save the plot as a PNG file, with the filename coming from the columnheader. What is the best way to go about this where text.png is replaced by the ith column header?
#!/bin/bash
set datafile separator ","
set key autotitle columnhead
set xlabel "time/date"
nc = "`awk -F, 'NR == 1{ print NF; exit}' input.csv`"
set term png
do for [i = 2:5] {
set output "test.png"
plot 'HiveLongrun.csv' every::0 using i:xticlabels(1) with lines
}

Answer 1

As long as you're using awk, you could use it once more to get the header name from inside a gnuplot macro:
#!/usr/bin/env gnuplot
set datafile separator ","
set key autotitle columnhead
set xlabel "time/date"
nc = "`awk -F, 'NR == 1{ print NF; exit}' input.csv`"
# Define a macro which, when evaluated, assigns the ith column header
# to the variable 'head'
awkhead(i) = "head = \"\`awk -F, 'NR == 1 {print $".i."}' input.csv\`\""
set term png
do for [i = 2:5] {
eval awkhead(i) # evaluate the macro
set output head.".png" # use the 'head' variable assigned by the macro
plot 'HiveLongrun.csv' every::0 using i:xticlabels(1) with lines
}
There is almost certainly a cleaner way to do this with another awk-like utility, or even within gnuplot. Gnuplot offers a few ways to run arbitrary internal/external commands, as you can see from my mix of backtics and macro evaluation.
By the way, it is a little strange to me that you have the bash shebang (#!/bin/bash) at the start of the script if it will presumably be interpreted by gnuplot. I assume you call it as gnuplot myscript.plt. In this case the shebang is just a comment (as far as gnuplot is concerned) and doesn't do anything because gnuplot is the interpreter. In my example I use #!/usr/bin/env gnuplot and I run the script as an executable in bash, like ./myscript.plt. The shebang in this case tells bash to make gnuplot the interpreter (or whatever command you would get by typing gnuplot at the command prompt). Of course you could also set the shebang to be #!/usr/bin/gnuplot if you're not worried about the path changing.