StageOrientationEvent only fires for upsideDown and default since ios6 - actionscript-3

Question

since updating to ios6, therefore having to get the beta AIR 3.5, it seems the StageOrientationEvent only fires for upsideDown and default, not rotatedRight and rotatedLeft anymore. I have read about the changes to orientation handling in ios6 but I cant seem to find a way round it for AIR AS3. Here is the code on my quick orientation testing app (just on the timeline for a quick test):
stage.autoOrients = true
stage.addEventListener(StageOrientationEvent.ORIENTATION_CHANGE, orientationChange);
stage.addEventListener(StageOrientationEvent.ORIENTATION_CHANGING, orientationChanging);
function orientationChange(e:StageOrientationEvent):void{
var t:TraceOnStage = new TraceOnStage(stage ,"----------------");
t= new TraceOnStage(stage, "orientationChange before: " + e.beforeOrientation + stage.orientation);
t = new TraceOnStage(stage, "orientationChange after: " + e.afterOrientation + stage.orientation);
}
function orientationChanging(e:StageOrientationEvent):void{
var t:TraceOnStage = new TraceOnStage(stage ,"----------------");
t = new TraceOnStage(stage, "orientationChanging before: " + e.beforeOrientation + stage.orientation);
t = new TraceOnStage(stage, "orientationChanging after: " + e.afterOrientation + stage.orientation);
}
When on the iPad it only traces for upside down and default, it worked fine until ios6. I have a whole series of orientation-requiring apps about to be finalized with the client waiting then this happened! Any ideas or help would be appreciated.

Answer 1

Try removing the
(aspectRatio) part in your application descriptor xml - orientation change works in every direction again.

Answer 2

As iOS6 has disabled these events there is nothing you can do to get them from AIR.
I don't think there's any easy solution but as all the accelerometer data should still be there, you should be able to construct your own event that tells you when the rotation has changed based on the accelerometer x, y, and z.

Answer 3

Ok I found one way to get around this orientation with the accelerometer problem. To avoid the confusion of changing accelerometer data each time orientation is changed, I decided to try not changing the stage orientation at all, going for rotating and repositioning the root to give the same effect instead. It works well but be aware any code in your app using the localToGlobal or stage mouseX and mouseY will need a extra line of code to use the root as positioning reference. Here is the whole class I wrote. Its in its first working stage so any comments for improvements welcome!
import flash.sensors.Accelerometer;
import flash.events.AccelerometerEvent;
import flash.events.EventDispatcher;
import flash.events.Event;
import flash.display.StageOrientation;
import flash.display.Stage;
import flash.display.DisplayObject;
import flash.utils.setInterval;
import flash.utils.clearInterval;
public class AcceleroOrientator extends EventDispatcher {
public static const ORIENTATION_CHANGE:String = "orientationChange";
public var currentOrientation:String = StageOrientation.DEFAULT
private var firstCheckOrientation:String = StageOrientation.DEFAULT;
private var theRoot:DisplayObject;
private var myConst:Number = Math.sin(Math.PI/4);
private var accl:Accelerometer;
private var inter:int;
private var inter2:int;
private var currenAcceleromResult:String;
private var checkFrequency:int = 500;
public function AcceleroOrientator(tRoot:DisplayObject) {
if (Accelerometer.isSupported) {
accl = new Accelerometer();
accl.setRequestedUpdateInterval(100);
} else {
trace("Accelerometer feature not supported!!");
}
theRoot = tRoot;
theRoot.stage.autoOrients = false;
}
public function set active(val:Boolean):void {
if (inter2){
clearInterval(inter2);
}
if (val==true) {
if (! accl.hasEventListener(AccelerometerEvent.UPDATE)){
accl.addEventListener(AccelerometerEvent.UPDATE, getAcceleromOrientation);
}
currentOrientation = currenAcceleromResult;
inter2 = setInterval(checkOrientation, checkFrequency);
} else {
if (accl.hasEventListener(AccelerometerEvent.UPDATE)){
accl.removeEventListener(AccelerometerEvent.UPDATE, getAcceleromOrientation);
}
}
}
private function checkOrientation():void {
firstCheckOrientation = currenAcceleromResult;
if (inter){
clearInterval(inter);
}
if (currentOrientation != firstCheckOrientation) {
inter = setInterval(confirmOrientation, checkFrequency/3);
}
}
private function confirmOrientation():void{
if (inter){
clearInterval(inter);
}
var secondCheckOrientation = currenAcceleromResult;
if (firstCheckOrientation == secondCheckOrientation){
currentOrientation = firstCheckOrientation;
doRootRotation();
dispatchEvent(new Event(ORIENTATION_CHANGE));
}
}
private function doRootRotation():void{
if (currentOrientation == StageOrientation.ROTATED_LEFT){
theRoot.rotation = 90;
theRoot.x = theRoot.stage.stageWidth;
theRoot.y = 0;
} else if (currentOrientation == StageOrientation.DEFAULT) {
theRoot.rotation = 0;
theRoot.x = 0;
theRoot.y = 0;
} else if (currentOrientation == StageOrientation.ROTATED_RIGHT) {
theRoot.rotation = -90;
theRoot.x = 0;
theRoot.y = theRoot.stage.stageHeight;
} else if (currentOrientation == StageOrientation.UPSIDE_DOWN) {
theRoot.rotation = 180;
theRoot.x = theRoot.stage.stageWidth;
theRoot.y = theRoot.stage.stageHeight;
}
}
private function getAcceleromOrientation(e:AccelerometerEvent):void{
if (Math.abs(e.accelerationZ) > myConst){
return;
}
if (e.accelerationX > 0 && e.accelerationY > - myConst && e.accelerationY < myConst) {
currenAcceleromResult = StageOrientation.ROTATED_LEFT;
} else if ( e.accelerationY >= myConst) {
currenAcceleromResult = StageOrientation.DEFAULT;
} else if (e.accelerationX < 0 && e.accelerationY > -myConst && e.accelerationY < myConst) {
currenAcceleromResult = StageOrientation.ROTATED_RIGHT;
} else if (e.accelerationY <= myConst) {
currenAcceleromResult = StageOrientation.UPSIDE_DOWN;
} else {
currenAcceleromResult = StageOrientation.UNKNOWN;
}
}
}