What are the Access startup properties that can be changed using VBA - ms-access

Question

I have an app that uses the following procedure to change some of the Current DB properties.
Public Sub SetStartupOptions(propname As String, propdb As Variant, prop As Variant)
On Error GoTo Err_SetStartupOptions
'Set passed startup property.
'some of the startup properties you can use...
' "StartupShowDBWindow", DB_BOOLEAN, False
' "StartupShowStatusBar", DB_BOOLEAN, False
' "AllowBuiltinToolbars", DB_BOOLEAN, False
' "AllowFullMenus", DB_BOOLEAN, False
' "AllowBreakIntoCode", DB_BOOLEAN, False
' "AllowSpecialKeys", DB_BOOLEAN, False
' "AllowBypassKey", DB_BOOLEAN, False
Dim dbs As Object
Dim prp As Object
Set dbs = CurrentDb
If propname = "DBOpen" Then
dbs.Properties("AllowBreakIntoCode") = prop
dbs.Properties("AllowSpecialKeys") = prop
dbs.Properties("AllowBypassKey") = prop
dbs.Properties("AllowFullMenus") = prop
dbs.Properties("StartUpShowDBWindow") = prop
Else
dbs.Properties(propname) = prop
End If
Set dbs = Nothing
Set prp = Nothing
Exit_SetStartupOptions:
Exit Sub
Err_SetStartupOptions:
Select Case Err.Number
Case 3270
Set prp = dbs.CreateProperty(propname, propdb, prop)
Resume Next
Case Else
Dim ErrAns As Integer, ErrMsg As String
If ErrChoice = vbYesNoCancel Then
ErrMsg = Err.Description & ": " & Str(Err.Number) & vbNewLine & "Press 'Yes' to resume next;" & vbCrLf & _
"'No' to Exit Procedure." & vbCrLf & "or 'Cancel' to break into code"
Else
ErrMsg = Err.Description & ": " & Str(Err.Number) & vbNewLine & "Press 'Yes' to resume next;" & vbCrLf & _
"'No' to Exit Procedure."
End If
ErrAns = MsgBox(ErrMsg, _
vbCritical + vbQuestion + ErrChoice, "SetStartupOptions")
If ErrAns = vbYes Then
Resume Next
ElseIf ErrAns = vbCancel Then
On Error GoTo 0
Resume
Else
Resume Exit_SetStartupOptions
End If
End Select
End Sub
procedure can be used to add and set values for DB.properties, These are the properties that are set in the Access options screen. I have a limited list of property names but, does anyone know where I can find the full list of properties that are recognized? ( i.e. the startup form name, start up ribbon name,... )

Answer 1

You can list all of the properties for the database that exist at the time you run the code using a very simple procedure as seen here.
Public Sub ListDBProps()
Dim db As Database
Dim prp As Property
Set db = CurrentDb
For Each prp In db.Properties
Debug.Print prp.Name
Next prp
End Sub
There are a couple of gotcha's in this. Notice I said "that exist at the time you run the code". That is, Access creates properties for the database (and presumably other objects as well) on an "as needed" basis. For instance, when you compile the database into, what used to be called an MDE, now an ACCDE, Access will add a new property of Type "Text" [10] named "MDE" with a value of "T". There are a couple of properties in the list you provided that fall into this category as well, such as "AllowBypassKey" and "AllowBreakIntoCode".
Here is the list that I got when I ran this code on a simple database I opened up:
Name
Connect
Transactions
Updatable
CollatingOrder
QueryTimeout
Version
RecordsAffected
ReplicaID
DesignMasterID
Connection
ANSI Query Mode
Themed Form Controls
AccessVersion
NavPane Category
UseMDIMode
ShowDocumentTabs
Build
CheckTruncatedNumFields
ProjVer
StartUpShowDBWindow
StartUpShowStatusBar
AllowShortcutMenus
AllowFullMenus
AllowBuiltInToolbars
AllowToolbarChanges
AllowSpecialKeys
UseAppIconForFrmRpt
AllowDatasheetSchema
Show Values Limit
Show Values in Indexed
Show Values in Non-Indexed
Show Values in Remote
Auto Compact
DesignWithData
Picture Property Storage Format
NavPane Closed
NavPane Width
NavPane View By
NavPane Sort By
Track Name AutoCorrect Info
Perform Name AutoCorrect
HasOfflineLists
You can add the Type property to your output easily enough. It is an integer value corresponding to the DataTypeEnum enumeration. The Value property of the Property can be a little more tricky. Usually it's a value that can be easily converted to a string value but there are a couple that cause a runtime error when you try to print them out or store them in a String variable. A little error handling in a small function can handle that with no trouble.
My example was run on an ACCDB in Microsoft Access 2007.
Enjoy . . . Doug