find the matching items given in an array - actionscript-3

Question

i don't understand arrays in functions, but how do you find the matching items given in an array? for example:
var fruit:Array = ["apples", "oranges", "grapes", "oranges", "apples", "grapes"];
how can i get it to show only the number of apples in the array?

Answer 1

Simply, you can do this:
private function getCount(fruitArray:Array, fruitName:String):int {
var count:int=0;
for (var i:int=0; i<fruitArray.length; i++) {
if(fruitArray[i].toLowerCase()==fruitName.toLowerCase()) {
count++;
}
}
return count;
}
var fruit:Array = ["apples", "oranges", "grapes", "oranges", "apples", "grapes"];
var appleCount=getCount(fruit, "apples"); //returns 2
var grapeCount=getCount(fruit, "grapes"); //returns 2
var orangeCount=getCount(fruit, "oranges"); //returns 2

Answer 2

Depending on how many items are in the array, and how often you want to search for different items, it can get very costly to have a for loop iterate over the entire array, every time you want to count things (which would happen if you did what the other two answers suggest). You might want to have a count function that iterates over the array just once, and returns a list of counters, instead of a single number:
function countItems( arr:Array ) : Object {
var counts : Object = {};
for each ( var item : String in arr ) {
if (counts.hasOwnProperty(item)) counts[item]++;
else counts[item] = 1;
}
return counts;
}
var fruit:Array = ["apples", "oranges", "grapes", "oranges", "apples", "grapes"];
var counts : Object = countItems(fruit);
trace (counts["apples"]); // => 2
trace (counts["oranges"]); // => 2
trace (counts["grapes"]); // => 2

Answer 3

function countOccurrences( haystack, needle ){
var index : int = -1;
var counter : int = -1;
do{
counter++;
index = haystack.indexOf( needle, index + 1 );
}while( index >= 0 );
return counter;
}
var fruit:Array = ["apples", "oranges", "grapes", "oranges", "apples", "grapes"];
trace( countOccurrences( fruit, "apples" ) ); //outputs '2'

Answer 4

var stringToSearch:String = "apples";
var pattern:RegExp = new RegExp(/\b\b/.source+stringToSearch, "g");
var matches:Array = fruit.toString().match(pattern);
//
trace(matches.length);
Disclaimer: don't use this if you have many elements in your array (eg. fruit.length>1000): it is compact but it can be slower than any other solution posted here. Another thing to point out is that here I'm assuming your "matching items" are "strings".

Answer 5

Try something like
private function makeFilter(filterValue:String):Function {
var fn:Function = function (obj:Object, index:int=0, arr:Array=[]):Boolean {
if (String(obj)==filterValue) {
return true;
}
return false;
}
return fn;
}
//somewhere else:
var filterFunction:Function = makeFilter('apples');
var appleCount:int = fruit.filter(filterFunction).length;
FYI, more about this approach: http://www.gasi.ch/blog/functional-actionscript-1/

Answer 6

var matches = 0
var arrayMatcher = (array1, array2) => {
for (let i = 0; i <= array1 - 1; i++) {
var myFirstItem = array1[i];
for (a = 0; a <= array2.length - 1; a++) {
var mySecondItem = array2[a];
if (mySecondItem === myFirstItem) {
matches += 1;
}
}
}
return matches;
}
I used this to find matches in a list of a patient's symptoms with a list of common symptoms for a certain disease and it worked for me. You could give it a try! :)