Sending notification email based on query results - ms-access

Question

I have a query table which shows the "FirstName", "LastName", "DueDate". What I wanted to do is create a follow-up process. If the duedate is today (date()), access needs to send notification email to the one general email address.
My code works only for first record in the query, it doesn't goes to other records.
Here is the code that I am using for;
Public Sub FollowUpEmail()
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim oApp As Object
Dim oEmail As Object
Set oApp = CreateObject("Outlook.Application")
Set oEmail = oApp.CreateItem(0)
Set db = CurrentDb
strSQL = "SELECT FirstName, SurName, DueDate" & _
" FROM TestQuery"
Set rs = db.OpenRecordset(strSQL, dbOpenDynaset)
While Not rs.EOF
SendKeys "^{ENTER}"
With oEmail
.To = "xxx"
.Subject = rs.Fields("FirstName").Value & "/" & "Deadline"
.Body = "test"
.Display
End With
rs.MoveNext
Wend
rs.Close
Set rs = Nothing
Set db = Nothing
Set oApp = Nothing
Set oEmail = Nothing
End Sub

Answer 1

You will need to create & send a new email for every iteration of the loop, for example:
Public Sub FollowUpEmail()
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim oApp As Object
Set oApp = CreateObject("Outlook.Application")
Set db = CurrentDb
Set rs = db.OpenRecordset("SELECT FirstName, SurName, DueDate FROM TestQuery")
Do Until rs.EOF
With oApp.CreateItem(0)
.To = "xxx"
.Subject = rs!FirstName & "/" & "Deadline"
.Body = "test"
.Display
End With
rs.MoveNext
Loop
rs.Close
Set rs = Nothing
Set db = Nothing
Set oApp = Nothing
End Sub
Or, if you want to send the emails directly:
Public Sub FollowUpEmail()
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim oApp As Object
Set oApp = CreateObject("Outlook.Application")
Set db = CurrentDb
Set rs = db.OpenRecordset("SELECT FirstName, SurName, DueDate FROM TestQuery")
Do Until rs.EOF
With oApp.CreateItem(0)
.To = "xxx"
.Subject = rs!FirstName & "/" & "Deadline"
.Body = "test"
.Send
End With
rs.MoveNext
Loop
rs.Close
Set rs = Nothing
Set db = Nothing
Set oApp = Nothing
End Sub