When the error reappears error handling does not work - ms-access

Question

Logics:
User. Presses the button;
Code . Creates a "Recordset" "rstStud" (students) and "rstGroupStud" (Student Groups);
Code . Cycle. Enumerates "rstStud";
Code . Add entry to "rstGroupStud";
Code . If the record exists, go to the next record in the loop;
Code . If the entry is new, add an entry in "rstGroupStud";
Essence: one click of a button - add one unique entry.
Problem.
When the cycle passes! StudentName = "Student Name 2" in the line ".Update" I get an error.
Error:
"Failed to make changes due to duplicate values ​​in
index, primary key or relationships. Change the data in one
or multiple fields containing duplicate values
delete the index or override it by allowing
duplicate values ​​and try again. "
In other words, the first time the error handler works normally, and when I re-fire, I get an error.
Question.
How to make the code work according to the described logic?
Private Sub btnAddRecord_Click()
Dim nameStud As String
Dim rstStud As DAO.Recordset '
Dim rstGroupStud As DAO.Recordset '
Set rstStud = CurrentDb.OpenRecordset("tbl_02_Students", dbOpenSnapshot) '
Set rstGroupStud = CurrentDb.OpenRecordset("tbl_03_GruopsStudents", dbOpenDynaset) '
' *** rstStud
With rstStud
Do Until .EOF = True
nameStud = !nameStud
On Error GoTo errend
' *** rstGroupStud
With rstGroupStud
.AddNew
!idGroup = Me.id_GroupFrm
!nameStud = nameStud
' nameStud
.Update
End With
rstGroupStud.Close
Me.frm_03_GruopsStudents_tbl.Requery
Exit Sub
errend:
.MoveNext
Loop
End With
On Error Resume Next
rstStud.Close
Set rstStud = Nothing
End Sub
Update_1
File - link

Answer 1

You need to de-tangle the execution paths; normal and error execution states are intertwined, that's why any error beyond the first one can't be handled.
Private Sub btnAddRecord_Click()
Dim nameStud As String
Dim rstStud As DAO.Recordset '
Dim rstGroupStud As DAO.Recordset '
Set rstStud = CurrentDb.OpenRecordset("tbl_02_Students", dbOpenSnapshot) '
Set rstGroupStud = CurrentDb.OpenRecordset("tbl_03_GruopsStudents", dbOpenDynaset) '
' *** rstStud
With rstStud
Do Until .EOF = True
On Error GoTo ErrHandler
nameStud = !nameStud
' *** rstGroupStud
With rstGroupStud
.AddNew
!idGroup = Me.id_GroupFrm
!nameStud = nameStud
' nameStud
.Update
End With
rstGroupStud.Close
Me.frm_03_GruopsStudents_tbl.Requery
Exit Do
TryNext:
On Error Resume Next
.MoveNext
If Err.Number <> 0 Then Exit Do
On Error GoTo 0
Loop
End With
On Error Resume Next
rstStud.Close
Set rstStud = Nothing
On Error GoTo 0
Exit Sub
ErrHandler:
Resume TryNext
End Sub
That way ErrHandler only ever runs in an error state; TryNext runs in the "happy path", and Exit Do breaks out of the loop (but not out of the procedure) so that the cleanup code can run whatever the outcome is.

Answer 2

Don't do it in VBA. Do it in a query instead.
For example, you could do this way:
Create a query named qryAssignStudentsToGroup:
PARAMETERS id_GroupFrm INT;
INSERT INTO tbl_03_GruopsStudents (idGroup, nameStud)
SELECT id_GroupFrm, nameStud
FROM tbl_02_Students AS s
WHERE NOT EXISTS (
SELECT NULL
FROM tbl_03_GruopsStudents AS g
WHERE s.nameStud = g.nameStud
AND g.idGroup = id_GroupFrm
);
Then your code behind becomes:
Private Sub btnAddRecord_Click()
With CurrentDb.QueryDefs("qryAssignStudentsToGroup")
.Parameters("id_GroupFrm") = Me.id_GroupFrm
.Execute
End With
Me.frm_03_GruopsStudents_tbl.Requery
End Sub
This gives you much less code for same thing, and you eliminate the complexity around error handling simply by filtering out the rows. More importantly, you perform a bulk update once, rather than for each row you touch. This leverages the power of database engine. It's convenient to do things in a loop with a DAO.Recordset but that's row-by-agonizing-row programming. You really want to get in mindset of set-based programming.

Answer 3

You must call Err.Clear to reset the error state
errend:
Err.Clear
.MoveNext
I would call Me.frm_03_GruopsStudents_tbl.Requery after the loop. There is not point in requerying the form all the time.
But jumping to another regular code part instead of going to an error handler is not the usual way of handling errors. To address the possibility to handle errors on MoveNext, change the code like this:
Private Sub btnAddRecord_Click()
Dim nameStud As String
Dim rstStud As DAO.Recordset
Dim rstGroupStud As DAO.Recordset
Set rstStud = CurrentDb.OpenRecordset("tbl_02_Students", dbOpenSnapshot)
Set rstGroupStud = CurrentDb.OpenRecordset("tbl_03_GruopsStudents", dbOpenDynaset)
' *** rstStud
With rstStud
Do Until .EOF = True
nameStud = !nameStud
On Error GoTo UpdateError
' *** rstGroupStud
With rstGroupStud
.AddNew
!idGroup = Me.id_GroupFrm
!nameStud = nameStud
' nameStud
.Update
End With
rstGroupStud.Close
Me.frm_03_GruopsStudents_tbl.Requery
Exit Sub
continue_loop:
On Error GoTo MoveNextError
.MoveNext
Loop
End With
CleanUp:
On Error Resume Next
rstStud.Close
Set rstStud = Nothing
Exit Sub
UpdateError:
Resume continue_loop
MoveNextError:
MsgBox Err.Description
Resume CleanUp
End Sub
This pattern is extensible. You can add as many error handlers as required.