Exce VBA - Fetch links from a fetching-builds website - html

Question

I've been trying to fetch the data from "http://builds.reicast.com/" but the issue is the website is also fetching information (which is what I actually need; the Master dev-build URLs). I feel like the delay in loading the Javascript fetching is hindering the fetching process on my side. Also, I've tried several different ways of fetching the build-URL's but they never appear (I'm assuming it's the same issue as mentioned previously).
This is what it looks like:
Sub FetchData()
With ActiveSheet.QueryTables.Add(Connection:= _
"URL;http://builds.reicast.com/", Destination:=Range( _
"$A$1"))
.Name = "master"
.FieldNames = True
.RowNumbers = False
.FillAdjacentFormulas = False
.PreserveFormatting = True
.RefreshOnFileOpen = False
.BackgroundQuery = True
.RefreshStyle = xlInsertDeleteCells
.SavePassword = False
.SaveData = True
.AdjustColumnWidth = True
.RefreshPeriod = 0
.WebSelectionType = xlEntirePage
.WebFormatting = xlWebFormattingNone
.WebPreFormattedTextToColumns = True
.WebConsecutiveDelimitersAsOne = True
.WebSingleBlockTextImport = False
.WebDisableDateRecognition = False
.WebDisableRedirections = False
.Refresh BackgroundQuery:=False
End With
End Sub
How can I get it to load the "master dev-builds section"?
Thanks for your time!

Answer 1

You can use Microsoft Internet Explorer Controls Library added via VBE > Tools > References and include a timed loop to ensure links are present e.g.
Option Explicit
Public Sub GetLinks()
Dim ie As New InternetExplorer, commits As Object, t As Date
Const MAX_WAIT_SEC As Long = 10
With ie
.Visible = True
.Navigate2 "http://builds.reicast.com/"
While .Busy Or .readyState < 4: DoEvents: Wend
t = Timer
Do
Set commits = ie.document.querySelectorAll(".commit [href]")
If Timer - t > MAX_WAIT_SEC Then Exit Do
Loop While commits.Length = 0
Debug.Print commits.Length
Dim i As Long
For i = 0 To commits.Length - 1
With ActiveSheet
.Cells(i + 1, 1) = commits.item(i).innerText
.Cells(i + 1, 2) = commits.item(i).getAttribute("href")
End With
Next
Stop '<==Delete me later
.Quit
End With
End Sub
If you want to write out the whole table:
Option Explicit
Public Sub GetTable()
Dim ie As New InternetExplorer, hTable As Object, t As Date, headers(), ws As Worksheet
Const MAX_WAIT_SEC As Long = 10
headers = Array("Commit", "Date", "Android", "Win_x86", "Win_x64")
Set ws = ThisWorkbook.Worksheets("Sheet1")
With ie
.Visible = True
.Navigate2 "http://builds.reicast.com/"
While .Busy Or .readyState < 4: DoEvents: Wend
t = Timer
Do
On Error Resume Next
Set hTable = ie.document.querySelector("#builds table")
On Error GoTo 0
If Timer - t > MAX_WAIT_SEC Then Exit Do
Loop While hTable Is Nothing
Writetable hTable, 1, ws
ws.Cells(1, 1).Resize(1, UBound(headers) + 1) = headers
.Quit
End With
End Sub
Public Sub Writetable(ByVal hTable As Object, ByVal startRow As Long, ByVal ws As Worksheet)
Dim tr As Object, td As Object, r As Long, c As Long
For Each tr In hTable.getElementsByTagName("tr")
r = r + 1: c = 1
If r > 2 Then
For Each td In tr.getElementsByTagName("td")
Select Case c
Case 1, 3, 4, 5
ws.Cells(r - 1, c) = td.FirstChild
Case Else
ws.Cells(r - 1, c) = td.innerText
End Select
c = c + 1
Next
End If
Next
End Sub
Example output: