Need a Warning pop up message in Access - ms-access

Question

I want to use a VBA code to pop up a warning message in the start of my database and tell me the name of people that their ages passed 50 just for once the last i could reach is that
For i = 1 To 4
If [Forms]![1]![years] >=50 Then
MsgBox "employees:" & Me.name
End If
Next i

Answer 1

You can use my simple function:
Public Function AgeSimple( _
ByVal datDateOfBirth As Date) _
As Integer
' Returns the difference in full years from datDateOfBirth to current date.
'
' Calculates correctly for:
' leap years
' dates of 29. February
' date/time values with embedded time values
'
' DateAdd() is used for check for month end of February as it correctly
' returns Feb. 28. when adding a count of years to dates of Feb. 29.
' when the resulting year is a common year.
' After an idea of Markus G. Fischer.
'
' 2007-06-26. Cactus Data ApS, CPH.
Dim datToday As Date
Dim intAge As Integer
Dim intYears As Integer
datToday = Date
' Find difference in calendar years.
intYears = DateDiff("yyyy", datDateOfBirth, datToday)
If intYears > 0 Then
' Decrease by 1 if current date is earlier than birthday of current year
' using DateDiff to ignore a time portion of datDateOfBirth.
intAge = intYears - Abs(DateDiff("d", datToday, DateAdd("yyyy", intYears, datDateOfBirth)) > 0)
End If
AgeSimple = intAge
End Function
And a loop in the click event of a button on your form (example):
Dim rs As DAO.Recordset
Set rs = Me.RecordsetClone
If rs.RecordCount > 0 Then
rs.MoveFirst
End If
While Not rs.EOF
If AgeSimple(Nz(rs!DOB.Value, Date)) >= 50 Then
MsgBox "Employee: " & rs![Name].Value, vbInformation + vbOKOnly, "50+"
End If
rs.MoveNext
Wend
Set rs = Nothing
Of course, replace the field/control names here with those of your actual form.
Edit
A demo is here