SAS - formula for creation of one column from another - function

Question

My problem is following - I am creating a column (diskont_faktor) from another one (disc_pc_nonann) with the formula for creation differing based on the row number.
for row #1 the function is diskont_faktor = 1/disc_pc_nonann;
for row #2 to n the function is diskont_faktor = diskont_faktor(t-1)/disc_pc_nonann;
I tried following code:
data soubor2;
set srv.data;
disc_pc_nonann = (1+DISC_PC/100)**(1/12);
if _n_ = 1 then diskont_faktor = 1/disc_pc_nonann;
else diskont_faktor = lag1(diskont_faktor)/disc_pc_nonann;
run;
But SAS does not calculate values for rows > 1.
Is there some specific reason why function lag does not work in this setting of code ?
I tried even this version without success:
data soubor2;
set srv.data;
disc_pc_nonann = (1+DISC_PC/100)**(1/12);
if _n_ = 1 then diskont_faktor = 1/disc_pc_nonann;
else do; y=lag1(diskont_faktor);
diskont_faktor = y/disc_pc_nonann;
end;
run;
Thank you for any advice what I am doing wrong.

Answer 1

The LAG() function does not return the value from the previous observation. Instead it returns the previous value from the stack that it generates as it it is called. So by only executing the lag() for some of the observations you are not properly stacking the values.
One easy way to work around this is to place the value of the LAG() function call into a variable. That way it runs for every observation so it always returns the previous value. You can then conditionally reference the variable if you want without interrupting the stream of values for the LAG() function.
lag_diskont_faktor=lag(diskont_faktor);
if _n_ = 1 then diskont_faktor = 1/disc_pc_nonann;
else diskont_faktor = lag_diskont_faktor/disc_pc_nonann;
But for your problem it looks like you do not really need to use LAG(). You can just use RETAIN to prevent SAS from setting the new variable to missing when it starts the next iteration of the DATA step.
retain diskont_faktor;
if _n_ = 1 then diskont_faktor = 1/disc_pc_nonann;
else diskont_faktor = diskont_faktor/disc_pc_nonann;
You could even set the initial value for the variable in the RETAIN statement and simplify the code.
retain diskont_faktor 1;
diskont_faktor = diskont_faktor/disc_pc_nonann;

Answer 2

You need to initialize your variable diskont_faktor at the start of your program, so add an retain diskont_faktor; at the start.
The first call of lag1 returns you a . , because the queue is empty at that time, so for _n_ = 2 it would return nothing but store your value from _n_= 1 in the queue. _n_ = 3 should work but store your empty result from _n_=2 in the queue. Because for n=2 you had no result, _n_= 4 will return nothing again. This goes on and on, so that you have results for odd _n_ and no result for even _n_.
So i dont know how to solve this whith lag,
but I can provide you an alternative solution without lag:
data soubor2 (drop=diskont_faktor_old);
retain diskont_faktor_old;
set srv.data;
disc_pc_nonann = (1+DISC_PC/100)**(1/12);
if _n_ = 1 then diskont_faktor = 1/disc_pc_nonann;
else diskont_faktor = diskont_faktor_old/disc_pc_nonann;
diskont_faktor_old=diskont_faktor;
run;