MS Access VBA check that Word has been closed? - ms-access

Question

I have a project that requires me to open a document in Word and wait while the document is open. The user then needs to edit the document, print it or save it and then they will close it manually. When the document (or Word itself) is closed I would like to continue my VBA script in Access.
I have the following code
If Len(Dir(sDocName)) > 0 Then
Dim wordApp As Word.Application
Dim wordDoc As Word.Document
' Launch Word
Set wordApp = New Word.Application
' Open the document
With wordApp
Set wordDoc = .Documents.Open(sDocName, , False)
' Pass data
With wordDoc
.Variables("bmArchitectCompanyName").Value = "Hello"
.Variables("bmArchitectCompanyAddress").Value = "Hello"
.Variables("bmArchitectCompanyPostCode").Value = "Hello"
.Variables("bmArchitectContactFirstName").Value = "Hello"
.Variables("bmProjectTitle").Value = ProjectTitle
.Fields.Update
End With
.Visible = True
.Activate
Do Until wordApp Is Nothing
' Wait for Word to be closed
Loop
' Display a success message
MsgBox "Success!"
End With
End If
However, the do loop never exits.
How do I check if the document I launched through VBA has been closed by the user from my VBA code?

Answer 1

If your are handling the Word Document in a class module or form module, try declaring a Word.Document object this way:
Dim WithEvents w As Word.Document
then you can use the Word.Document object event "Close":
Private Sub w_Close()
'Things you want to do when the Word.Document is closed
'reset object
set w=nothing
End Sub
You must not let then "container" form close or the object terminate unless w is nothing. The form or the object are quiet (or whatever you want them to do) until your Word document is closed.

Answer 2

You must yield to the OS using DoEvents, then check if the document was closed, otherwise coninue the DoEvents loop. The following is outline code that I unfortunately could not test.
Do
DoEvents
For i = 1 to wordApp.Documents.Count
If (wordApp.Documents(i).Name = sDocName) Then Exit For
Next i
If (i > wordApp.Documents.Count) Then Exit Loop
Loop While (True)
Note: you probably don't want to close the application because maybe the user had other documents open. Maybe you should test that.

Answer 3

I have found the solution...
Do While .Visible
' wait until the window is no longer visible
Loop
Does exactly what I was looking for, waits until word is closed and then continues with the MS Access VBA script.

Answer 4

Building on what Paul has entered this uses a different method to test if the document is open.
Sub Test()
Dim wordApp As Word.Application
Dim wordDoc As Word.Document
Dim sDocName As String
sDocName = "<Full path to document>"
Set wordApp = New Word.Application
With wordApp
Set wordDoc = .Documents.Open(sDocName, , False)
.Visible = True
.Activate
Do
DoEvents
Loop While FileIsOpen(sDocName)
End With
MsgBox "Finished"
End Sub
Public Function FileIsOpen(FullFilePath As String) As Boolean
Dim ff As Long
On Error Resume Next
ff = FreeFile()
Open FullFilePath For Input Lock Read As #ff
Close ff
FileIsOpen = (Err.Number <> 0)
On Error GoTo 0
End Function

Answer 5

The issue with checking to see if wordApp Is Nothing is that VBA doesn't know to dereference the object when it is closed externally. In other words, when the document to which wordApp refers is closed, the pointer to the object becomes bogus but not Nothing. To trap for the event, you can do a meaningless call to the document object in the loop, and exit if an error occurs:
On Error Resume Next
With wordDoc
Do
DoEvents
'This will only occur if there is an error:
If .Visible<>.Visible Then Exit Do
Loop
End With
Err.Clear
On Error Goto 0

Answer 6

I just tested with no loop or anything else. The macro code in Access waited until the instance of the Word application was closed before it finished executing. Here's what I tested, and the MsgBox only executed after I quit Word:
' Open the document
With wordApp
Set wordDoc = .Documents.Add
' Pass data
With wordDoc
.Variables("bmArchitectCompanyName").Value = "Hello"
.Variables("bmArchitectCompanyAddress").Value = "Hello"
.Variables("bmArchitectCompanyPostCode").Value = "Hello"
.Variables("bmArchitectContactFirstName").Value = "Hello"
.Content.Text = "test"
'.Variables("bmProjectTitle").Value = ProjectTitle
'.Fields.Update
End With
.Visible = True
.Activate
' Display a success message
MsgBox "Success!"
Set wordDoc = Nothing
Set wordApp = Nothing
End With
Note that you want to be sure to set the objects to Nothing or
you're likely to get error messages the next time you run the code
because it will leave the instance of WinWord open in memory.