How to print multiple html files on Windows 8 with VBS - html

Question

I have a folder containing 1650 HTML files that, due to local authorities, must be also printed in paper form.
I have tried with classic ctrl+A (even if I was trying on smaller quantities) and then I have looked for PRINT label in the right click menu, but there's any.
If I choose to print multiple jpg or pdf files, the PRINT voice appears.
How am I supposed to print multiple html files? A batch file? (I have no knowledge about how to).
I have also thought to convert html to pdf, but had no success with PDF Creator and PDF Architect.
Any of you with some experience to share?
I have wrtten some code mixing the one given by Tim and what I found on stackoverflow, but had no success.
Here it is:
Set objFSO = CreateObject("Scripting.FileSystemObject")
objStartFolder = "C:\Users\mainUser\Desktop\ft"
Set objFolder = objFSO.GetFolder(objStartFolder)
Set colFiles = objFolder.Files
For Each objFile in colFiles
strFileName = objFile.Name
If objFSO.GetExtensionName(strFileName) = "html" Then
On Error Resume Next
Const OLECMDID_PRINT = 6
Const OLECMDEXECOPT_DONTPROMPTUSER = 2
Const PRINT_WAITFORCOMPLETION = 2
Dim objExplorer
Set objExplorer = CreateObject("InternetExplorer.Application")
objExplorer.Navigate objFolder.Path +"\"+ objFile.Name
objExplorer.Visible = 1
Do while objExplorer.ReadyState <> 4
WScript.Sleep 1000 'milliseconds
Loop
oIExplorer.ExecWB OLECMDID_PRINT, OLECMDEXECOPT_DONTPROMPTUSER
End If
Next
It just opens one html in internet explorer. I thought it would have open all the files, and already in PRINT "mode".
I think I am missing something.

Answer 1

See this thread for looping through files in a directory: How to do something to each file in a directory with a batch script
Then you can use the native PRINT command so your batch file could be as simple as this:
for /f "delims=|" %%f in ('dir /b c:\') do PRINT %%f
In light of the comments below:
Ahh. Then you will likely have to automate IE to print the page. Play with a VBScript along these lines:
Const OLECMDID_PRINT = 6
Const OLECMDEXECOPT_DONTPROMPTUSER = 2
Const PRINT_WAITFORCOMPLETION = 2
objStartFolder = "C:\Users\mainUser\Desktop\ft"
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(objStartFolder)
Set objExplorer = CreateObject("InternetExplorer.Application")
Set oShell = CreateObject("Shell.Application")
For Each objFile In objFolder.Files
strFileName = objFile.Name
If objFSO.GetExtensionName(strFileName) = "html" Then
handle = objExplorer.Hwnd
objExplorer.Navigate objFolder.Path + "\" + objFile.Name
For Each Wnd In oShell.Windows
If handle = Wnd.Hwnd Then Set objExplorer = Wnd
Next
Do While objExplorer.Busy
WScript.Sleep 1000 'milliseconds
Loop
objExplorer.ExecWB OLECMDID_PRINT, OLECMDEXECOPT_DONTPROMPTUSER
End If
Next
Set oShell = Nothing
Set objFSO = Nothing
Set objFolder = Nothing
Set objExplorer = Nothing
3rd Update:
I fixed the code above. I apologize.Its been some time since I've worked with IE. Apparently IE treats each tab as a new instance of IE, and loading a document "creates" a new tab. As a result, we have to load the page and then find our IE window again so we can set it back to the variable.