Change Access server connection from command line - ms-access

Question

I have inherited an Access 2007 ADP application that uses a SQL Server 2008 backend. Is it possible to change the server connection used by the application from the command line or by some VBScript? At the moment, when I am releasing the application to a test/UAT/production environment, I have to open the project, change the server connection, and save it again.
I am trying to automate the build process as much as possible, and currently this is one of the last remaining manual tasks.

Answer 1

Hmm, my Google-fu is weak. I just found an article on MSDN which gives the VBA script to achieve this. I modified it to run as a VBScript below:
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")
If (WScript.Arguments.Count = 0) Then
WScript.Echo "ERROR - the Access project name must be specified"
WScript.Quit()
End If
Dim sAccessProject
sAccessProject = fso.GetAbsolutePathName(WScript.Arguments(0))
If (fso.FileExists(sAccessProject) = False) Then
WScript.Echo "ERROR - the Access project could not be located : " & sAccessProject
WScript.Quit()
End If
If (WScript.Arguments.Count = 1) Then
WScript.Echo "ERROR - the SQL Server hostname must be specified"
WScript.Quit()
End If
Dim sServer
sServer = WScript.Arguments(1)
If (WScript.Arguments.Count = 2) Then
WScript.Echo "ERROR - the SQL Server database name must be specified"
WScript.Quit()
End If
Dim sDatabase
sDatabase = WScript.Arguments(2)
Dim sUsername
If (WScript.Arguments.Count = 3) Then
sUsername = ""
Else
sUsername = WScript.Arguments(3)
End If
Dim sPassword
If (WScript.Arguments.Count >= 3) Then
sPassword = ""
Else
sPassword = WScript.Arguments(4)
End If
ChangeADPConnection sAccessProject, sServer, sDatabase, sUsername, sPassword
Function ChangeADPConnection(strProjectName, strServerName, strDBName, strUN , strPW)
Dim strConnect
Dim oApplication
Set oApplication = CreateObject("Access.Application")
WScript.Echo "Starting MS Access"
WScript.Echo "Opening " & strProjectName & " ..."
oApplication.OpenAccessProject strProjectName
oApplication.Visible = false
oApplication.CurrentProject.CloseConnection
'The Provider, Data Source, and Initial Catalog arguments are required.
strConnect = "Provider=SQLOLEDB.1" & _
";Data Source=" & strServerName & _
";Initial Catalog=" & strDBName
If strUN <> "" Then
strConnect = strConnect & ";User ID=" & strUN
If strPW <> "" Then
strConnect = strConnect & ";Password=" & strPW
End If
Else 'Try to use integrated security if no username is supplied.
strConnect = strConnect & ";Integrated Security=SSPI"
End If
WScript.Echo "Setting connection string to " & strConnect
oApplication.CurrentProject.OpenConnection strConnect
oApplication.Quit()
Set oApplication = Nothing
End Function
To run it, just use the following from the commandline:
cscript connect.vbs Project.adp, "ServerName", "DatabaseName", "Username", "Password"