ActionScript 3 onMetaData video duration - can't store value - actionscript-3

Question

I have standard NetStream for video connection in AS3:
The Code:
public class VideoInit extends MovieClip
{
import flash.media.Video;
import flash.net.NetConnection;
import flash.net.NetStream;
import flash.events.NetStatusEvent;
public var video:Video;
public var nc:NetConnection;
public var ns:NetStream;
public var meta:Object;
public var _duration; // <----- the variable
public function VideoInit()
{
video = new Video(480,270);
addChild(video);
nc = new NetConnection();
nc.connect(null);
ns = new NetStream(nc);
meta = new Object();
ns.client = meta;
video.attachNetStream(ns);
ns.play("video.f4v");
meta = new Object();
meta.onMetaData = function(meta:Object) // <---- the method
{
_duration = meta.duration
}
ns.client = meta;
}
Now, everyime that the onMetaData method executes, the variable _duration stores the value, but right after the debugger step leaves the method, _duration value is set back to unindentified.
I've tried to do a workaround with Array, by pushing the value, but the same thing happens, the Array resets. What could it be wrong?
Edit:
Any object that stores the duration value self destructs as soon as onMetaData is complete. Doesn't really matter how I Implement it.

Answer 1

The code you've posted would not compile and, even if it did, it could cause other problems.
Suggestion: ditch the meta Object and instead set ns.client = this;
This works:
package
{
import flash.events.Event;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.media.Video;
import flash.net.NetConnection;
import flash.net.NetStream;
import flash.events.NetStatusEvent;
public class VideoInit extends Sprite
{
private var video:Video;
private var nc:NetConnection;
private var ns:NetStream;
private var _duration:Number; // <----- the variable
public function VideoInit()
{
addEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
}
private function onAddedToStage(e:Event):void
{
removeEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
video = new Video(480,270);
addChild(video);
nc = new NetConnection();
nc.connect(null);
ns = new NetStream(nc);
ns.client = this;// meta;
video.attachNetStream(ns);
ns.play("video.f4v");
stage.addEventListener(MouseEvent.MOUSE_DOWN, testTheValueOfDuration);
}
public function onMetaData(e:Object):void
{
_duration = e.duration
trace('_duration:', _duration);
testTheValueOfDuration();
}
private function testTheValueOfDuration(e:MouseEvent = null):void
{
trace('Seriously, what is the value of _duration?', _duration);
}
}
}